Definitions

Clear[x,y,z,BT];

(* Lorenz System *)
σ=2;ρ=15;β=.2;
eq={x'[t]==σ(y[t]-x[t]),y'[t]==x[t](ρ-z[t])-y[t],z'[t]==x[t]y[t]-β z[t]};

(* Butterfly Transform *)
k=.09;f0=0;
BT[{x_,y_,z_}]:={x Cos[k z+f0]+y Sin[k z+f0],y Cos[k z+f0]-x Sin[k z+f0],z};

References:
  [1] The Butterfly Effect : Application of Chaotic Dynamics for Design

ODE Integration

Clear[Traj];
(* Solution for given initial conditions and integration time *)
Traj[r0_,T_]:=Module[{Δt=.02,sol},
sol=NDSolve[Append[eq,{x[0],y[0],z[0]}==r0],{x,y,z},{t,0,T}]//First;
(* resampling and applying the Butterfly Transform: *)
BT/@(Evaluate[{x[t],y[t],z[t]}/.sol/.t->#]&/@Range[0,T,Δt])
];

(* Trajectories *)
traj1=Traj[{-.65,-.5,20},3000];(* Orange *)
traj2=Traj[{.65,.5,20},600];(* Black *)
traj3=Traj[{-1.73,-1.73,14},210];(* White *)

Final Plot

d=1; (* downsampling ratio: =1 for full quality; >1 for better performance *)
thic=.05;
btf=Graphics3D[{
,Tube[traj1[[;;;;d]],thic],Sphere[traj1[[1]],.2],
,Tube[traj2[[;;;;d]],1.004thic],Sphere[traj2[[1]],.2],
,Tube[traj3[[;;;;d]],thic],Sphere[traj3[[1]],.2],
(* second white trajectory by symmetry: *)
,Tube[{-1,-1,1}*#&/@traj3[[;;;;d]],thic],Sphere[{-1,-1,1}*traj3[[1]],.2] 
},
ViewVertical->{0, 0, 1},ViewPoint->{5,-.05,-.1},
BoxRatios->{1, 1, 1},Boxed->True,
Lighting->{
{"Ambient",GrayLevel[.35]},
{"Directional",RGBColor[{0.37,0.37,0.37}],ImageScaled[{2,0,2}]},{"Directional",GrayLevel[.37],ImageScaled[{2,2,2}]},
{"Directional",GrayLevel[.37],ImageScaled[{0,2,2}]},
{"Directional",GrayLevel[.37],{0,5,0}}}
]